首頁>Program>source

是否有可以在两列中計數並且仅返迴唯一計數的公式。
我有一个表,其中两列可以有一个" X",我想計算這个" X"的"或"。
意思是如果它在一个或另一个列或两个列中,則算上,否則就不算。

示例:

A       B        C
foo      X
bar               X
Doo      X        X
Boo          
  

預期結果為3(foo,bar,Doo)。
我做不到 因為那会给我4.
=COUNTIF(B:B, "X") + COUNTIF(C:C, "X") 返迴4.
=COUNTIF(B:C , "X") = 1, SUMPRODUCT((B:B="X")*(C:C="X")*1) = 4

有没有公式可以算出這種情况?

不幸的是,我没有Office 365工作

SUMPRODUCT((B:C="X")*1)
最新回復
  • 1月前
    1 #

    在D列中使用concat公式,例如D1 = CONCAT(A1,B1),D2 = CONCAT(A2,B2)等等.

    D1=CONCAT(A1,B1)
    

    然後希望在D列上使用counta函式對所有非空白的單元格进行計數,希望如此簡單。

    =COUNTA(D:D)
    

    這對您有帮助吗?

    或者尝試尝試

    = COUNTIFS(B:B, "X",C:C, "") + COUNTIFS(B:B, "",C:C, "X") + COUNTIFS(B:B, "X",C:C, "X")
    

  • 1月前
    2 #

    如果您拥有Excel O365,則可以尝試:

    =COUNTA(UNIQUE(FILTER(A:A,(B:B="X")+(C:C="X"))))
    

    如果您使用的是旧版Excel,請尝試:

    =SUM(--(FREQUENCY(IF((B1:B4="X")+(C1:C4="X")>0,MATCH(A1:A4,A1:A4,0)),ROW(A1:A4))>0))
    

    不是,這最後一个公式是O365之前的Excel中CSE輸入的公式.另外,如果您的資料从另一行開始,則需要相應地調整公式.

  • 1月前
    3 #

    如果您具有Excel365,則可以使用 FILTER()COUNTA()一起使用

    =COUNTA(FILTER(A1:A4,(B1:B4="x")+(C1:C4="x")))
    

  • 1月前
    4 #

    請參见下面的 SUMPRODUCT實現 對您有用。

    =SUMPRODUCT(--ISNUMBER(SEARCH("X",B2:B5&C2:C5,1)))

    或者它需要嚴格並且避免诸如萬用字元匹配之類的問题,然後您也可以尝試:

    =SUMPRODUCT(--(((B2:B5="X")+(C2:C5="X"))>0))

  • 如何使用Java泛型解決這種情况?
  • javascript:jQuery使用最接近的方法添加按钮屬性